Practical Learning: Introducing Stored Procedures


  1. Start Microsoft SQL Server Management Studio and log in to your server
  2. On the main menu, click File -> New -> Query With Current Connection
  3. To create a new database, copy and paste the following code in the Query window:
     
    -- =============================================
    -- Database: WattsALoan
    -- =============================================
    USE master
    GO
    -- Drop the database if it already exists
    IF  EXISTS (
     SELECT name 
      FROM sys.databases 
      WHERE name = N'WattsALoan'
    )
    DROP DATABASE WattsALoan
    GO

    CREATE DATABASE WattsALoan
    GO
    -- =========================================
    -- Table: Employees
    -- =========================================
    USE WattsALoan
    GO

    IF OBJECT_ID(N'dbo.Employees', N'U') IS NOT NULL
      DROP TABLE dbo.Employees
    GO

    CREATE TABLE dbo.Employees
    (
        EmployeeID int identity(1,1) NOT NULL,
        EmployeeNumber nchar(10) NULL,
        FirstName nvarchar(20) NULL,
        LastName nvarchar(10),
        FullName AS ((LastName+ ', N') + FirstName),
        Title nvarchar(100),
        HourlySalary money,
        Username nvarchar(20),
        Password nvarchar(20),
        CONSTRAINT PK_Employees PRIMARY KEY(EmployeeID)
    )
    GO
    INSERT INTO dbo.Employees(EmployeeNumber, FirstName, LastName, Title, HourlySalary)
    VALUES(N'293747', N'Jeanne', N'Tryler', N'Accounts Manager', 22.24);
    GO
    INSERT INTO dbo.Employees(EmployeeNumber, FirstName, LastName, Title, HourlySalary)
    VALUES(N'492947', N'Helene', N'Gustman', N'Accounts Representative', 14.55);
    GO
    INSERT INTO dbo.Employees(EmployeeNumber, FirstName, LastName, Title, HourlySalary)
    VALUES(N'804685', N'Ernest', N'Thomas', N'Accounts Representative', 12.75);
    GO
    -- =========================================
    -- Table: LoanTypes
    -- =========================================
    USE WattsALoan
    GO

    IF OBJECT_ID(N'dbo.LoanTypes', N'U') IS NOT NULL
      DROP TABLE dbo.LoanTypes
    GO

    CREATE TABLE dbo.LoanTypes
    (
        LoanTypeID int identity(1,1) NOT NULL, 
        LoanType nvarchar(50) NOT NULL, 
        CONSTRAINT PK_LoanTypes PRIMARY KEY(LoanTypeID)
    );
    GO
    INSERT INTO LoanTypes(LoanType) VALUES(N'Personal Loan');
    GO
    INSERT INTO LoanTypes(LoanType) VALUES(N'Car Financing');
    GO
    INSERT INTO LoanTypes(LoanType) VALUES(N'Credit Card');
    GO
    INSERT INTO LoanTypes(LoanType) VALUES(N'Furniture Loan');
    GO
    -- =========================================
    -- Table: Customers
    -- =========================================
    USE WattsALoan
    GO

    IF OBJECT_ID(N'dbo.Customers', N'U') IS NOT NULL
      DROP TABLE dbo.Customers
    GO

    CREATE TABLE dbo.Customers
    (
        CustomerID int identity(1,1) NOT NULL,
        DateCreated datetime2 NULL,
        FullName nvarchar(50) NOT NULL,
        BillingAddress nvarchar(100),
        BillingCity nvarchar(50),
        BillingState nvarchar(50),
        BillingZIPCide nvarchar(10),
        EmailAddress nvarchar(100),
        CONSTRAINT PK_Customers PRIMARY KEY(CustomerID)
    )
    GO
    INSERT INTO Customers(DateCreated, FullName,
        BillingAddress, BillingCity, BillingState,
        BillingZIPCide, EmailAddress)
    VALUES(N'2/26/2004', N'Julius Ramse',
           '927 Feuler Ave', N'Silver Spring', 
           'MD', N'20904', N'ramses1990@netscape.net');
    GO
    INSERT INTO Customers(DateCreated, FullName,
        BillingAddress, BillingCity, BillingState,
     BillingZIPCide)
    VALUES(N'06/22/2006', N'Gertrude Vaillant',
           '10055 Larsenic Rd', N'Takoma Park', 
           'MD', N'20910');
    GO
    INSERT INTO Customers(DateCreated, FullName,
        BillingAddress, BillingCity, BillingState,
     BillingZIPCide, EmailAddress)
    VALUES(N'12/3/2004', N'James Barrouch',
           '4204 Fallon Drive', N'Silver Spring',
           'MD', N'20906', N'barrouchj@hotmail.com');
    GO
    INSERT INTO Customers(DateCreated, FullName,
        BillingAddress, BillingCity, BillingState,
     BillingZIPCide)
    VALUES(N'08/02/2006', N'Christine Rougher',
           '825 Manning Street', N'Alexandria', 
           'VA', N'22231');
    GO
    INSERT INTO Customers(DateCreated, FullName,
        BillingAddress, BillingCity, BillingState,
     BillingZIPCide, EmailAddress)
    VALUES(N'10/08/2006', N'Patrick Heller',
           '2480 Clarington Drive NW', N'Washington', 
           'DC', N'20006', N'hellerp@yahooo.com');
    GO
    -- =========================================
    -- Table: LoanAllocation
    -- =========================================
    USE WattsALoan
    GO

    IF OBJECT_ID(N'dbo.LoanAllocations', N'U') IS NOT NULL
      DROP TABLE dbo.LoanAllocations
    GO

    CREATE TABLE dbo.LoanAllocations
    (
        LoanAllocationID int identity(1,1) NOT NULL,
        DatePrepared datetime2 NOT NULL, 
        EmployeeID int NULL
      CONSTRAINT FK_LoanPreparer
      FOREIGN KEY REFERENCES Employees(EmployeeID),
        CustomerID int NOT NULL
      CONSTRAINT FK_LoanReceiver
      FOREIGN KEY REFERENCES Customers(CustomerID),
        AccountNumber nchar(10),
        LoanTypeID int NOT NULL
      CONSTRAINT FK_LoanTypes
      FOREIGN KEY REFERENCES LoanTypes(LoanTypeID),
        LoanAmount money NOT NULL,
        InterestRate decimal(6,2) NOT NULL,
        Periods decimal(6,2) NOT NULL,
        InterestAmount AS ((LoanAmount*(InterestRate/(100)))*(Periods/(12))),
        FutureValue AS (LoanAmount+(LoanAmount*(InterestRate/(100)))*(Periods/(12))),
        MonthlyPayment AS ((LoanAmount+(LoanAmount*(InterestRate/(100)))*(Periods/(12)))/Periods),
        Notes Text,
        CONSTRAINT PK_LoanAllocations PRIMARY KEY(LoanAllocationID)
    )
    GO
    INSERT INTO LoanAllocations(DatePrepared, EmployeeID,
     CustomerID, AccountNumber, LoanTypeID, LoanAmount,
        InterestRate, Periods, Notes)
    VALUES(N'2/26/2004', 2, 1, N'9171394', 4, 6500.00, 12.65, 36, 
           'The loan will be delivered by our furniture business partner Helios Furnian');
    GO
    INSERT INTO LoanAllocations(DatePrepared, EmployeeID,
     CustomerID, AccountNumber, LoanTypeID, LoanAmount,
        InterestRate, Periods, Notes)
    VALUES(N'06/22/2007', 2, 2, N'8628064', 2, 16500.00, 10.20, 60, 
           'For this car loan, our partner Arlington Honda will process and deliver the car.');
    GO
    INSERT INTO LoanAllocations(DatePrepared, EmployeeID,
     CustomerID, AccountNumber, LoanTypeID, LoanAmount,
        InterestRate, Periods, Notes)
    VALUES(N'12/3/2006', 1, 3, N'8468364', 3, 500.00, 18.65, 48, 
           'This is a regular credit card.');
    GO
    INSERT INTO LoanAllocations(DatePrepared, EmployeeID,
     CustomerID, AccountNumber, LoanTypeID, LoanAmount,
        InterestRate, Periods, Notes)
    VALUES(N'08/02/2006', 3, 4, N'2483047', 1, 3500.00, 12.74, 36, 
           'This is personal/cash loan allocated to a customer who walked in the store and requested it.');
    GO
    INSERT INTO LoanAllocations(DatePrepared, EmployeeID,
     CustomerID, AccountNumber, LoanTypeID, LoanAmount,
        InterestRate, Periods, Notes)
    VALUES(N'10/08/2006', 2, 5, N'1311804', 4, 22748.36, 12.28, 60, 
           'This is a regular car financing loan');
    GO
    -- =========================================
    -- Table: Payments
    -- =========================================
    USE WattsALoan
    GO

    IF OBJECT_ID(N'dbo.Payments', N'U') IS NOT NULL
      DROP TABLE dbo.Payments
    GO

    CREATE TABLE dbo.Payments
    (
        PaymentID int identity(1, 1) NOT NULL,
        PaymentDate datetime2 NOT NULL, 
        EmployeeID int NULL
      CONSTRAINT FK_Employees
      FOREIGN KEY REFERENCES Employees(EmployeeID),
        LoanAllocationID int NOT NULL
      CONSTRAINT FK_LoanAllocations
      FOREIGN KEY REFERENCES LoanAllocations(LoanAllocationID),
        PaymentAmount money NOT NULL,
        Balance money,
        Notes Text,
        CONSTRAINT PK_Payments PRIMARY KEY(PaymentID)
    )
    GO
  4. To execute the code, press F5
  5. In the Object Explorer, expand the Databases node if necessary and expand WattsALoan
  6. Click Database Diagram
  7. When the message box comes up, read it and click Yes
  8. Right-click Database Diagram and click New Database Diagram...
  9. In the dialog box, double-click each table and, when all tables have been added, click Close

  10. Save the diagram as dgmWattsALoan and close it
Creating a Stored Procedure
To create a procedure:
  • In the Object Explorer, expand the database for which you want to create the procedure, expand its Programmability node, right-click Stored Procedures, and click New Stored Procedure... A query window with a skeleton syntax would be displayed. You can then modify that code using the techniques we will learn in this lesson.
  • Open an empty query window associated with the database for which you want to create the stored procedure and display the Templates Explorer. In the Templates Explorer, expand the Store Procedure node. Drag Create Stored Procedure and drop it in the query window
  • Open an empty query window associated with the database for which you want to create the stored procedure and enter the necessary code
In SQL, to create a procedure, you start with the CREATE PROCEDURE expression. You can also use CREATE PROC. Both expressions produce the same result. Like everything in your database, you must name your procedure:
  • The name of a procedure can be any string that follows the rules we reviewed for naming the functions
  • Refrain from starting the name of a procedure with sp_ because it could conflict with some of the stored procedures that already ship with Microsoft SQL Server.
After the name of the procedure, type the keyword AS. The section, group of words, or group of lines after the AS keyword is called the body of the procedure. It states what you want the procedure to do or what you want it to produce.
Based on this, the simplest syntax of creating a procedure is:
CREATE PROCEDURE ProcedureName
AS
Body of the Procedure
It is important to keep in mind that there are many other issues related to creating a procedure but for now, we will consider that syntax.
After creating the procedure, you must store it as an object in your database. To do this, on the SQL Editor toolbar, you can click the Execute button . If the code of the procedure is right, it would be created and a new node for its name would be added to the Stored Procedures section of the database.
Managing Procedures

Modifying a Procedure
As a regular SQL Server database object, you can modify a stored procedure without recreating it. To do this:
  • In the Object Explorer, you can right-click the procedure and click Modify
  • In the Object Explorer, you can right-click the procedure, position the mouse on Script Stored Procedure As -> ALTER To -> New Query Editor Window
  • Open an empty query window associated with the database that contains the stored procedure. From the Templates Explorer, expand Stored Procedure. Drag the Drop Stored Procedure node and drop it in the empty query window
In each case, a skeleton code would be generated for you. You can then edit it to create a new version of your stored procedure. After editing the code, you can execute the SQL statement to update the stored procedure.
In SQL, the basic formula to modify a stored procedure is:
ALTER PROCEDURE ProcedureName
AS
Body of Procedure
Deleting a Procedure
One of the biggest characteristics of a stored procedure is that it is treated like an object in its own right. Therefore, after creating it, if you don't need it anymore, you can get rid of it.
There are various types of stored procedures, some of which are considered temporary. Those types of procedures delete themselves when not needed anymore, such as when the person who created the stored procedure disconnects from the database or shuts down the computer. Otherwise, to delete a procedure, you can use either the Object Explorer or SQL. As mentioned with tables, even if you create a procedure using the Object Explorer, you can delete it using SQL and vice-versa.
To remove a procedure in the Object Explorer, after expanding its database, its Programmability, and its Stored Procedure nodes, you can right-click the stored procedure and click Delete. You can also click it in the Object Explorer to select it and then press Delete. The Delete Object dialog box would come up to let you make a decision.
To delete a procedure in SQL, the syntax to use is:
DROP PROCEDURE ProcedureName
Of course, you should make sure you are in the right database and also that the ProcedureNameexists.
Exploring Procedures

Introduction
Probably the simplest procedure you can write would consist of selecting columns from a table. This is done with the SELECT operator and applying the techniques we reviewed for data analysis. For example, to create a stored procedure that would hold a list of students from a table named Students, you would create the procedure as follows:
CREATE PROCEDURE GetStudentIdentification
AS
BEGIN
    SELECT FirstName, LastName, DateOfBirth, Gender
    FROM Students
END
GO
Besides SELECT operations, in a stored procedure, you can perform any of the database operations we have applied so far. These include creating and maintaining records, etc.
Practical LearningPractical Learning: Creating a Stored Procedure
  1. Make sure you have the Yugo National Bank database created in the Lesson13. If you didn't create it, do it now.
    In the Object Explorer, right-click YugoNationalBank and click New Query
  2. To start a stored procedure, type the following:
     
    USE YugoNationalBank;
    GO
    -- =============================================
    -- Author: FunctionX
    -- Create date: Friday, May 25, 2007
    -- Description: This stored procedure assigns a 
    --              default password to each employee.
    -- =============================================

    CREATE PROCEDURE AssignDefaultPassword 
    AS
    BEGIN
     UPDATE dbo.Employees
     SET Password = N'Password1' FROM dbo.Employees;
    END
    GO
  3. To create the stored procedure, press F5
Executing a Procedure
To get the results of creating a stored procedure, you must execute it (in other words, to use a stored procedure, you must call it). To execute a procedure, you use the EXECUTE keyword followed by the name of the procedure. Although there are some other issues related to executing a procedure, for now, we will consider that the simplest syntax to call a procedure is:
EXECUTE ProcedureName
Alternatively, instead of EXECUTE, you can use the EXEC keyword:
EXEC ProcedureName
For example, if you have a procedure named GetStudentIdentification, to execute it, you would type:
EXECUTE GetStudentIdentification
You can also precede the name of the procedure with its schema, such as dbo. Here is an example:
EXECUTE dbo.GetStudentIdentification;
You can also precede the name of the schema with the name of the database. Here is an example:
EXECUTE ROSH.dbo.GetStudentIdentification;
Practical LearningPractical Learning: Executing a Stored Procedure
  1. Delete the contents of the query window and replace it with the following:
     
    EXECUTE AssignDefaultPassword;
    GO
  2. To execute the stored procedure, press F5
Using Expressions and Functions
One of the advantages of using a stored procedure is that not only can it produce the same expression as we saw during analysis but also it can store such an expression to be recalled any time without having to re-write it (the expression). Based on this, you can create an expression that combines a first and a last name to produce and store a full name. Here is an example:
CREATE PROCEDURE GetStudentIdentification
AS
BEGIN
    SELECT FullName = FirstName + ' ' + LastName,
           DateOfBirth, Gender
    FROM Students
END
GO
A stored procedure can also call a function in its body. To do this, follow the same rules we reviewed for calling functions during data analysis. Here is an example of a stored procedure that calls a function:
USE ROSH;
GO
CREATE PROCEDURE GetStudentsAges
AS
BEGIN
    SELECT FullName = FirstName + N' ' + LastName,
           DATEDIFF(year, DateOfBirth, GETDATE()) AS Age,
           Gender
    FROM Students
END
GO
Here is an example of executing the procedure:
Procedure
Practical LearningPractical Learning: Calling a Function in a Stored Procedure
  1. Delete the contents of the query window
  2. To start a new stored procedure, type the following:
     
    USE YugoNationalBank;
    GO

    -- =============================================
    -- Author:  FunctionX
    -- Create date: Friday, May 25, 2007
    -- Description: This stored procedure creates a
    --              username for each employee.
    --              It also assigns an email to the employee.
    -- =============================================
    CREATE PROCEDURE CreateUsername
    AS
    BEGIN
     UPDATE dbo.Employees
     SET Username = LOWER(LEFT(FirstName, 1) + LEFT(LastName, 5))
      FROM dbo.Employees;
     UPDATE dbo.Employees
     SET EmailAddress = LOWER(LEFT(FirstName, 1) + LEFT(LastName, 5)) +
            N'@yugonationalbank.com'
            FROM dbo.Employees;
    END
    GO
  3. To create the stored procedure, press F5
  4. Delete the contents of the query window and replace it with the following:
     
    EXECUTE CreateUsername;
    GO
  5. To execute the stored procedure, press F5
Arguments and Parameters

Introduction
All of the stored procedures we have created and used so far assumed that the values they needed were already in a table of the database. In some cases, you may need to create a stored procedure that involves values that are not part of the database. On such a scenario, for the procedure to carry its assignment, you would supply it with one or more values. 
An external value that is provided to a stored procedure is called a parameter. When you create a stored procedure, you must also create the parameter if you judge it necessary. When a procedure's creation is equipped with a parameter, it is said that the stored procedure takes an argument. A stored procedure can also take more than one argument.
When you execute a stored procedure that takes one or more arguments, you must provide a value for each argument. In this case, you are said to pass a value for the argument. There are cases when you don't have to provide an argument.
Passing Arguments
To create a stored procedure that takes an argument, type the formula CREATE PROCEDURE orCREATE PROC followed by the name of the procedure, then type the name of the argument starting with @. The parameter is created like a column of a table. That is, a parameter must have a name, a data type and an optional length. Here is the syntax you would use:
CREATE PROCEDURE ProcedureName
@ParameterName DataType
AS
Body of the Procedure
When implementing the stored procedure, you can define what you want to do with the parameter(s), in the body of the procedure. One way you can use a parameter is to run a query whose factor the user would provide. For example, imagine you want to create a procedure that, whenever executed, would be supplied with a gender, then it would display the list of students of that gender. Since you want the user to specify the gender of students to display, you can create a stored procedure that receives the gender. Here is an example:
CREATE PROC GetListOfStudentsByGender
       @Gdr NVARCHAR(12)
AS
SELECT FirstName, LastName,
       DateOfBirth, HomePhone, Gender
FROM   Students
WHERE  Gender = @Gdr
Practical LearningPractical Learning: Creating a Stored Procedure
  1. Delete the contents of the query window and, to pass arguments to a stored procedure, type the following in the window:
     
    USE WattsALoan;
    GO

    CREATE PROCEDURE SpecifyCurrentBalance
        @PmtDate datetime2,
        @EmplID int,
        @LaID int,
        @PmtAmt money
    AS
    BEGIN
        -- Get the amount that was lent to the customer
        DECLARE @AmountOfLoan money;
        SET @AmountOfLoan = (SELECT las.FutureValue
                             FROM LoanAllocations las
                             WHERE (las.LoanAllocationID = @LaID));

        -- If the customer had already made at least one payment,
        -- get the current balance of the customer's account
        DECLARE @CurrentBalance money;
        SET     @CurrentBalance = (SELECT MIN(pay.Balance)
                                   FROM Payments pay
                                   WHERE (pay.LoanAllocationID = @LaID));

        -- If the customer has never made a payment (yet),
        -- to specify the balance, subtract the current payment
        -- from the original amount of the loan
        IF      @CurrentBalance IS NULL
     BEGIN
         INSERT INTO Payments(PaymentDate, EmployeeID,
         LoanAllocationID, PaymentAmount, Balance)
         VALUES(@PmtDate, @EmplID, @LaID, @PmtAmt,
             @AmountOfLoan - @PmtAmt);
     END
        -- If the customer had already at least one payment,
        -- subtract the current payment from the previous balance
        ELSE
     BEGIN
         INSERT INTO Payments(PaymentDate, EmployeeID,
        LoanAllocationID, PaymentAmount, Balance)
         VALUES(@PmtDate, @EmplID, @LaID,
             @PmtAmt, @CurrentBalance - @PmtAmt);
     END
    END
    GO
  2. To create the stored procedure, press F5
Executing an Argumentative Stored Procedure
As mentioned already, when executing a stored procedure that takes a parameter, make sure you provide a value for the parameter. The syntax used is:
EXEC ProcedureName ParameterValue
If the parameter is Boolean or numeric, make sure you provide the value as 0 or for a Boolean value or another number for the numeric type. If the parameter is a character or a string, type its value in single-quotes. Here is an example:
EXEC ROSH.dbo.GetListOfStudentsByGender N'Male';
Here is an example of executing it:
Procedure
Notice that we could/should have omitted to include the Gender column in the statement since it would be implied to the user.
Another type of stored procedure can be made to take more than one parameter. In this case, create the parameters in the section before the AS keyword, separated by a comma. The syntax you would use is:
CREATE PROCEDURE ProcedureName
@ParameterName1 DataType, @ParameterName2 DataType, @ParameterName_n DataType
AS
Body of the Procedure
Here is an example:
USE ROSH;
GO
CREATE PROCEDURE IdentifyStudentsByState
 @Gdr nvarchar(20),
 @StateOrProvince char(2)
AS
BEGIN
    SELECT FullName = LastName + ', N' + FirstName,
           DATEDIFF(year, DateOfBirth, GETDATE()) AS Age,
           Gender
    FROM Students
    WHERE (Gender = @Gdr) AND (State = @StateOrProvince)
END
GO
When calling a stored procedure that takes more than one parameter, you must still provide a value for each parameter but you have two alternatives. The simplest technique consists of providing a value for each parameter in the exact order they appear in the stored procedure. Here is an example:
USE ROSH;
GO
EXEC ROSH.dbo.IdentifyStudentsByState 'Female', N'MD';
GO
This would produce:
Procedure
Alternatively, you can provide the value for each parameter in the order of your choice. Consider the following procedure that takes 3 arguments:
USE ROSH;
GO
CREATE PROCEDURE IdentifySomeStudents
 @Gdr nvarchar(20),
 @StateOrProvince nchar(2),
 @HomeStatus bit
AS
BEGIN
    SELECT FullName = LastName + N', ' + FirstName,
           DATEDIFF(year, DateOfBirth, GETDATE()) AS Age,
           Gender
    FROM Students
    WHERE (Gender = @Gdr) AND 
          (State  = @StateOrProvince) AND
          (SPHome = @HomeStatus)
END
GO
When calling this type of procedure, you can type the name of each parameter and assign it the corresponding value. Here is an example:
USE ROSH;
GO
EXEC IdentifySomeStudents @HomeStatus=1, @StateOrProvince=N'MD', @Gdr=N'Female';
GO
Here is an example of executing the procedure:
Procedure
Practical LearningPractical Learning: Executing an Argumentative Procedure
  1. Delete the contents of the code window and, to create a stored procedure, type the following in the window:
     
    USE WattsALoan;
    GO
    EXECUTE SpecifyCurrentBalance '03/25/2004', 2, 1, 249.08;
    GO
    EXECUTE SpecifyCurrentBalance '01/30/2006', 2, 5, 611.93;
    GO
    EXECUTE SpecifyCurrentBalance '04/20/2004', 1, 1, 249.08;
    GO
    EXECUTE SpecifyCurrentBalance '10/28/2006', 2, 4, 134.38;
    GO
  2. To execute, press F5
Default Arguments
Imagine you create a database for a department store and a table that holds the list of items sold in the store:

Supposed you have filled the table with a few items as follows:

ItemNumberItemCategoryIDItemNameItemSizeUnitPrice
2648502Long-Sleeve Jersey DressPetite39.95
9304054Solid Crewneck TeeMedium12.95
2930041Cotton Comfort Open Bottom PantXLarge17.85
9245151Hooded Full-Zip SweatshirtS69.95
4059453Plaid Pinpoint Dress Shirt22 35-3635.85
2949362Cool-Dry Soft Cup Bra36D15.55
2945452Ladies Hooded SweatshirtMedium45.75
8204652Cotton Knit BlazerM295.95
2946942Denim Blazer - Natural BrownLarge75.85
9240943Texture-Striped Pleated Dress Pants44x3032.85
3594053Iron-Free Pleated Khaki Pants32x3239.95
1920043Sunglasses15.85
Imagine you want to create a mechanism of calculating the price of an item after a discount has been applied to it. Such a procedure can be created as follows:
CREATE PROC CalculateNetPrice
@discount Decimal
AS
SELECT ItemName, UnitPrice - (UnitPrice * @discount / 100)
FROM StoreItems
This can be executed as follows:
If you are planning to create a stored procedure that takes an argument and know that the argument will likely have the same value most of the time, you can provide that value as parameter but leave a room for other values of that argument. A value given to an argument is referred to as default. What this implies is that, when the user calls that stored procedure, if the user doesn't provide a value for the argument, the default value would be used.
To create a stored procedure that takes an argument that carries a default value, after declaring the value, on its right side, type = followed by the desired value. Here is an example applied to the above database:
CREATE PROC CalculateDiscountedPrice
@discount decimal = 10.00
AS
    SELECT ItemName, UnitPrice - (UnitPrice * @discount / 100)
    FROM StoreItems;
GO
When executing a stored procedure that takes a default argument, you don't have to provide a value for the argument if the default value suits you. Based on this, the above stored procedure can be called as follows:
If the default value doesn't apply to your current calculation, you can provide a value for the argument. Here is an example:
Using this same approach, you can create a stored procedure that takes more than one argument with default values. To provide a default value for each argument, after declaring it, type the desired value to its right side. Here is an example of a stored procedure that takes two arguments, each with a default value:
CREATE PROC CalculateSalePrice
@Discount decimal = 20.00,
@TaxRate  decimal = 7.75
AS
SELECT ItemName As [Item Description],
       UnitPrice As [Marked Price],
       UnitPrice * @Discount / 100 As [Discount Amt],
       UnitPrice - (UnitPrice * @Discount / 100) As [After Discount],
       UnitPrice * @TaxRate / 100 As [Tax Amount],
       (UnitPrice * @TaxRate / 100) + UnitPrice - 
       (UnitPrice * @Discount / 100) + (@TaxRate / 100) As [Net Price]
FROM StoreItems;
GO
Here is an example of executing the procedure:
When calling a stored procedure that takes more than one argument and all arguments having default values, you don't need to provide a value for each argument, you can provide a value for only one or some of the arguments. The above procedure can be called with one argument as follows:
EXEC CalculateSalePrice2 55.00
In this case, the other argument(s) would use their default value.
We saw that, when calling a stored procedure that takes more than one argument, you didn't have to provide the values of the arguments in the exact order they appeared in the procedure, you just had to type the name of each argument and assign it the desired value. In the same way, if a stored procedure takes more than one argument and some of the arguments have default values, when calling it, you can provide the values in the order of your choice, by typing the name of each argument and assigning it the desired value. Based on this, the above stored procedure can be called with only the value of the second argument as follows:
EXEC CalculateSalePrice2 @TaxRate = 8.55
In this case, the first argument would use its default value.
Practical LearningPractical Learning: Using Default Arguments
  1. Delete the contents of the query window
  2. To created a new version for a stored procedure we used earlier, type the following in the window:
     
    USE WattsALoan;
    GO
    DROP PROCEDURE SpecifyCurrentBalance;
    GO
    CREATE PROCEDURE SpecifyCurrentBalance
     @PmtDate datetime2,
     @EmplID int,
     @LaID int,
            @PmtAmt money,
            @Comments Text = N''
    AS
    BEGIN
     -- Get the amount that was lent to the customer
     DECLARE @AmountOfLoan money;
     SET @AmountOfLoan = (SELECT las.FutureValue
                                     FROM LoanAllocations las
                                     WHERE (las.LoanAllocationID = @LaID));

     -- If the customer had already made at least one payment,
     -- get the current balance of the customer's account
     DECLARE @CurrentBalance money;
     SET     @CurrentBalance = (SELECT MIN(pay.Balance)
                                       FROM Payments pay
                                       WHERE (pay.LoanAllocationID = @LaID));

     -- If the customer has never made a payment (yet),
     -- to specify the balance, subtract the current payment
     -- from the original amount of the loan
     IF      @CurrentBalance IS NULL
     BEGIN
      INSERT INTO Payments(PaymentDate, EmployeeID,
         LoanAllocationID, PaymentAmount,
                            Balance, Notes)
      VALUES(@PmtDate, @EmplID, @LaID, @PmtAmt,
             @AmountOfLoan - @PmtAmt, @Comments);
     END
     -- If the customer had already at least one payment,
     -- subtract the current payment from the previous balance
     ELSE
     BEGIN
      INSERT INTO Payments(PaymentDate, EmployeeID,
        LoanAllocationID, PaymentAmount,
         Balance, Notes)
      VALUES(@PmtDate, @EmplID, @LaID,
             @PmtAmt, @CurrentBalance - @PmtAmt, @Comments);
     END
    END
    GO
  3. To create the stored procedure, press F5
  4. Delete the contents of the query window
  5. To use the stored procedure, type the following:
     
    USE WattsALoan;
    GO

    EXECUTE SpecifyCurrentBalance '07/15/2004', 3, 1, 498.16,
      'The customer sent a double-payment to cover this and last month';
    GO
    EXECUTE SpecifyCurrentBalance '01/26/2007', 1, 3, 50;
    GO
    EXECUTE SpecifyCurrentBalance '08/26/2004', 2, 1, 249.08;
    GO
    EXECUTE SpecifyCurrentBalance '02/28/2006', 3, 5, 611.93;
    GO
    EXECUTE SpecifyCurrentBalance '10/24/2007', 2, 2, 415.25;
    GO
    EXECUTE SpecifyCurrentBalance '05/30/2004', 1, 1, 249.08;
    GO
    EXECUTE SpecifyCurrentBalance '02/22/2007', 2, 3, 20;
    GO
    EXECUTE SpecifyCurrentBalance '03/23/2006', 2, 5, 611.93;
    GO
    EXECUTE SpecifyCurrentBalance '07/22/2007', 2, 2, 415.25,
           'First regular payment';
    GO
    EXECUTE SpecifyCurrentBalance '12/24/2006', 1, 5, 611.93;
    GO
    EXECUTE SpecifyCurrentBalance '04/25/2006', 3, 5, 611.93;
    GO
    EXECUTE SpecifyCurrentBalance '09/26/2007', 2, 2, 415.25;
    GO
    EXECUTE SpecifyCurrentBalance '09/24/2006', 3, 4, 134.38;
    GO
    EXECUTE SpecifyCurrentBalance '03/25/2007', 2, 3, 25;
    GO
    EXECUTE SpecifyCurrentBalance '11/28/2006', 2, 5, 611.93,
     'First Car Payment';
    GO
    EXECUTE SpecifyCurrentBalance '08/28/2007', 1, 2, 415.25,
     'Second payment';
    GO
Output Parameters
Transact-SQL uses the notion of passing an argument by reference. This type of argument is passed to a procedure but it is meant to return a value. In other words, you can create a stored procedure that takes a parameter but the purpose of the parameter is to carry a new value when the procedure ends so you can use that value as you see fit.
To create a parameter that will return a value from the stored procedure, after the name of the procedure, if you want the stored procedure to take arguments, type them. Otherwise, omit them. On the other hand, you must pass at least one argument, name it starting with the @ symbol, specify its data type, and enter the OUTPUT keyword on its right. Based on this, the basic syntax you can use is:
CREATE PROCEDURE ProcedureName
@ParameterName DataType OUTPUT
AS
Body of the Procedure
In the body of the procedure, you can perform the assignment as you see fit. The primary rule you must follow is that, before the end of the procedure, you must have specified a value for the OUTPUT argument. That's the value that the argument will hold when the stored procedure exits. Here is an example:
CREATE PROCEDURE dbo.CreateFullName
    @FName nvarchar(20),
    @LName nvarchar(20), 
    @FullName nvarchar(42) OUTPUT
AS
    SELECT @FullName = @LName + ', N' + @FName
GO
When calling the stored procedure, you must pass an argument for the OUTPUT parameter and, once again, you must type OUTPUT to the right side of the argument. Remember that the stored procedure would return the argument. This means that, after calling the procedure, you can get back the OUTPUT argument and use it as you see fit. Here is an example:
DECLARE @FirstName nvarchar(20),
 @LastName nvarchar(20),
        @Full nvarchar(42)
SET @FirstName = N'Melanie';
SET @LastName = N'Johanssen';

EXECUTE dbo.CreateFullName @FirstName, @LastName, @Full OUTPUT

SELECT @Full;
GO
One of the advantages of using a function or a stored procedure is that it has access to the tables and records of its database. This means that you can access the columns and records as long as you specify the table or the view, which is done with a FROM clause associated with aSELECT statement. Consider the following stored procedure created in a database that contains a table named Students:
USE ROSH;
GO

CREATE PROCEDURE ShowStudentsFullNames
    @FullName nvarchar(42) OUTPUT
AS
    SELECT @FullName = LastName + ', N' + FirstName FROM Students;
GO
When you execute this stored procedure, it would work on the records of the table. One of the particularities of a stored procedure that takes an OUTPUT argument is that it can return only one value. Consider the following example of executing the above procedure:
When calling such a procedure, if you don't specify a condition to produce one particular result, the SQL interpreter in this case would select the last record. This means that you should always make sure that your stored procedure that takes an OUTPUT parameter would have a way to isolate a result. If the stored procedure processes a SELECT statement, you can use a WHEREcondition. Here is an example of such a procedure:
USE ROSH;
GO

CREATE PROCEDURE ShowStudentsFullNames
    @FullName nvarchar(42) OUTPUT
AS
    SELECT @FullName = LastName + ', N' + FirstName FROM Students
    WHERE StudentID = 8;
GO
When this procedure is executed, it would produce only the record stored in the 8th position of the table.

Lesson Summary
 
Exercises

  1. Create a stored procedure named ProcessPayroll that takes 11 arguments:
    1. The number of hours worked for the first week (passed by value)
    2. The number of hours worked for the second week (passed by value)
    3. A number that represents the number of regular hours worked for the two weeks (passed by reference)
    4. A number for the salary paid for the regular hours of the two weeks (passed by reference)
    5. A number that represents the number of overtime hours worked for the two weeks (passed by reference)
    6. A number for the salary paid for the overtime hours of the two weeks (passed by reference)
    7. A number that represents the net salary paid for that payroll (passed by reference)
  2.